100 DEFSHR KEYSOR%,BAS10:KEYSOR%=3:DEFSHR SELECT%,BAS87:SELECT%=0:DEFSHR MSTOP%,BAS89:MSTOP%=0:DEFSHR NUML%,S_60B:NUML%=1
110 OPEN "SETUP.DAT" FOR RANDOM AS #1 LEN = 52
120 FIELD #1,5 AS SIL$,5 AS SOL$,5 AS SQL$,5 AS SPL$,5 AS SCL$,4 AS SSCLT$,1 AS SLPC$,1 AS SH$,15 AS SIP$,4 AS SPORT$,2 AS LFCR$
130 GET #1,1
140 ILEN$=SIL$:OLEN$=SOL$:QLEN$=SQL$:PLEN$=SPL$:CLEN$=SCL$:SCLT$=SSCLT$:LPC$=SLPC$:HOST$=SH$:IP$=SIP$:PORT$=SPORT$:CLOSE #1
150 OPEN "PROMPT.DAT" FOR RANDOM AS #2 LEN = 82
160 FIELD #2,16 AS SPMT1$,16 AS SPMT2$,16 AS SPMT3$,16 AS SPMT4$,16 AS SPMT5$,2 AS LFCR$
170 GET #2,1
180 PMT1$=SPMT1$:PMT2$=SPMT2$:PMT3$=SPMT3$:PMT4$=SPMT4$:PMT5$=SPMT5$
190 CLOSE #2
200 ON ERROR GOSUB 5990:TRM$=CHR$(13)+CHR$(10):ESP$="        ":SSP$="      ":TSP$="   ":DEFSHR G1#,WT110:DEFSHR G2#,WT210
210 ILEN#=VAL(ILEN$):OLEN#=VAL(OLEN$):PLEN#=VAL(PLEN$):CLEN#=VAL(CLEN$):QLEN#=VAL(QLEN$):KEYSOR%=3
220 S$="N":INPUT "^INIT TABLES?   ^N,Y",S$
230 IF S$="N" THEN GOTO 580
240 V$="N":S$="N":INPUT "^INIT INBOUND?  ^N,Y",S$
250 IF S$="Y" THEN GOSUB 1280
260 IF V$="Y" THEN GOSUB 1360
270 V$="N":S$="N":INPUT "^INIT QUICK?    ^N,Y",S$
280 IF S$="Y" THEN GOSUB 1280
290 IF V$="Y" THEN GOSUB 1540
300 V$="N":S$="N":INPUT "^INIT OUTBOUND? ^N,Y",S$
310 IF S$="Y" THEN GOSUB 1280
320 IF V$="Y" THEN GOSUB 1450
330 V$="N":S$="N":INPUT "^INIT PERM?     ^N,Y",S$
340 IF S$="Y" THEN GOSUB 1280
350 IF V$="Y" THEN GOSUB 1630
360 V$="N":S$="N":INPUT "^INIT COMODITY? ^N,Y",S$
370 IF S$="Y" THEN GOSUB 1280
380 IF V$="Y" THEN GOSUB 1720
390 V$="N":S$="N":INPUT "^INIT BADGE?    ^N,Y",S$
400 IF S$="Y" THEN GOSUB 1280
410 IF V$="Y" THEN GOSUB 1820
420 GOTO 220
430 S$="N":INPUT "^CLEAR REPORTS? ^N,Y",S$
440 IF S$="N" THEN GOTO 580
450 S$="N":V$="N":INPUT "^CLEAR INBOUND? ^N,Y",S$
460 IF S$="Y" THEN V$="N":GOSUB 1280
470 IF V$="Y" THEN GOSUB 1980
480 S$="N":V$="N":INPUT "^CLEAR TRANS?    ^N,Y",S$
490 IF S$="Y" THEN V$="N":GOSUB 1280
500 IF V$="Y" THEN GOSUB 2120
510 S$="N":V$="N":INPUT "^CLEAR PERM?    ^N,Y",S$
520 IF S$="Y" THEN V$="N":GOSUB 1280
530 IF V$="Y" THEN GOSUB 2200
540 S$="N":V$="N":INPUT "^CLEAR COMMOD?  ^N,Y",S$
550 IF S$="Y" THEN V$="N":GOSUB 1280
560 IF V$="Y" THEN GOSUB 2290
570 
580 S$="N":INPUT "^CLEAR ACCUMS?  ^N,Y",S$
590 IF S$="N" THEN GOTO 700
600 S$="N":V$="N":INPUT "^CLEAR PERM?    ^N,Y",S$
610 IF S$="Y" THEN V$="N":GOSUB 1280
620 IF V$="Y" THEN GOSUB 2200
630 S$="N":V$="N":INPUT "^CLEAR COMMOD?  ^N,Y",S$
640 IF S$="Y" THEN V$="N":GOSUB 1280
650 IF V$="Y" THEN GOSUB 2290
660 S$="N":V$="N":INPUT "^CLEAR SCALE?   ^N,Y",S$
670 IF S$="Y" THEN V$="N":GOSUB 1280
680 IF V$="Y" THEN S1$="       00":S2$="       00":PRINT "Clearing...":SLEEP 3000
690 GOTO 580
700 S$="N":INPUT "^DELETE RECORD? ^N,Y",S$
710 IF S$="N" THEN GOTO 790
720 S$="N":V$="N":INPUT "^DELETE INBOUND?^N,Y",S$
730 IF S$="Y" THEN V$="N":GOSUB 1280
740 IF V$="Y" THEN GOSUB 2380
750 S$="N":V$="N":INPUT "^DELETE QUICK?  ^N,Y",S$
760 IF S$="Y" THEN V$="N":GOSUB 1280
770 IF V$="Y" THEN GOSUB 2510
780 GOTO 700
790 S$="N":INPUT "^PERMANENT?    ^N,Y",S$
800 IF S$="N" THEN GOTO 870
810 S$="N":INPUT "^ADD PERMNENT?  ^N,Y",S$
820 IF S$="Y" THEN GOSUB 2640
830 S$="N":INPUT "^EDIT TARE WT?  ^N,Y",S$
840 IF S$="Y" THEN GOSUB 2960
850 S$="N":INPUT "^DEL PERMNENT?  ^N,Y",S$
860 IF S$="Y" THEN GOSUB 3170
870 S$="N":INPUT "^COMMODITIES?   ^N,Y",S$
880 IF S$="N" THEN GOTO 990
890 INPUT "^ENABLE COMOD?  ^N,Y",COMDTY$
900 IF COMDTY$="N" THEN GOTO 990
910 S$="N":INPUT "^NEW COMMOD?    ^N,Y",S$
920 IF S$="Y" THEN GOSUB 3570
930 S$="N":INPUT "^EDIT FACTORS?  ^N,Y",S$
940 IF S$="Y" THEN GOSUB 3890
950 S$="N":INPUT "^DEL COMMOD?    ^N,Y",S$
960 IF S$="Y" THEN GOSUB 4120
970 S$="N":INPUT "^SORT COMMOD?   ^N,Y",S$
980 IF S$="Y" THEN GOSUB 4280
990 S$="N":INPUT "^BADGE READER?  ^N,Y",S$
1000 IF S$="N" THEN GOTO 1070
1010 INPUT "^ENABLE READER? ^N,Y",EBDG$
1020 IF EBDG$="N" THEN GOTO 1070
1030 S$="N":INPUT "^ADD BADGE?     ^N,Y",S$
1040 IF S$="Y" THEN GOSUB 4440
1050 S$="N":INPUT "^DELETE BADGE?  ^N,Y",S$
1060 IF S$="Y" THEN GOSUB 4780
1070 S$="N":INPUT "^COMMENTS?      ^N,Y",S$
1080 IF S$="Y" THEN GOSUB 3430
1090 V$="N":S$="N":INPUT "^LOOP DETECTORS?^N,Y",S$
1100 IF S$="Y" THEN GOSUB 1280
1110 IF V$="Y" THEN S$=LPC$:INPUT "^ENABLE LOOPS?  ^N,Y",S$:LPC$=S$
1120 V$="N":S$="N":INPUT "^HOST COMM?     ^N,Y",S$
1130 IF S$="Y" THEN GOSUB 1280
1140 IF V$="Y" THEN GOSUB 5920
1150 V$="N":S$="N":INPUT "^SET TIME/DATE? ^N,Y",S$
1160 IF S$="Y" THEN GOSUB 1280
1170 IF V$="Y" THEN GOSUB 4910
1180 S$="N":INPUT "^SET PASSWORD?  ^N,Y",S$
1190 IF S$="Y" THEN GOSUB 3290
1200 S$="N":INPUT "^PRINT SETUP?   ^N,Y",S$
1210 IF S$="Y" THEN GOSUB 5020
1220 V$="N":S$="N":INPUT "^RESET FACTORY? ^N,Y",S$
1230 IF S$="Y" THEN GOSUB 1280
1240 IF V$="Y" THEN GOSUB 5320
1250 S$="N":INPUT "^EXIT SETUP?    ^N,Y",S$
1260 IF S$="N" THEN GOTO 110 ELSE GOSUB 5250:PRINT " EXITING SETUP!"
1270 CHAIN "FILE1.BAS"
1280 S$="N":INPUT "^ARE YOU SURE?  ^N,Y",V$:RETURN
1290 VAL%=0
1300 IF LEN(NVAL$) > 5 THEN VAL%=1
1310 FOR K% = 1 TO LEN(NVAL$)
1320 K$=MID$(NVAL$,K%,1)
1330 IF ASC(K$)<46 OR ASC(K$)>57 OR ASC(K$)=47 THEN VAL%=1
1340 NEXT K%
1350 RETURN
1360 INPUT "Enter Table Size",ILEN$:LEN$=ILEN$:GOSUB 1890:GOSUB 1940:PRINT "FREE MEMORY ";MEM$:SLEEP 1000
1370 IF BAD%=1 THEN PRINT DISP$:SLEEP 2000:GOTO 1360
1380 KILL "INBOUND.DAT":ASS$="0":PRINT "Initializing... "
1390 OPEN "INBOUND.DAT" FOR RANDOM AS #1 LEN=36
1400 FIELD #1, 8 AS REC_ID$, 8 AS IN_WT$, 8 AS IN_T$, 10 AS IN_D$, 2 AS LFCR$
1410 FOR I%=1 TO ILEN#
1420 LSET REC_ID$=ESP$:RSET IN_WT$=ESP$:RSET IN_T$=ESP$:RSET IN_D$=SPACE$(10):LSET LFCR$=TRM$:PUT #1,I%
1430 NEXT I%
1440 CLOSE #1:ILEN$=PADL$(ILEN$,5," "):ILEN$=RIGHT$(ILEN$,5):RETURN
1450 INPUT "Enter Table Size",OLEN$:LEN$=OLEN$:GOSUB 1890:GOSUB 1940:PRINT "FREE MEMORY ";MEM$:SLEEP 1000
1460 IF BAD%=1 THEN PRINT DISP$:SLEEP 2000:GOTO 1450
1470 KILL "OUTBOUND.DAT":PRINT "Initializing... "
1480 OPEN "OUTBOUND.DAT" FOR RANDOM AS #2 LEN = 77
1490 FIELD #2,8 AS A$,8 AS B$,8 AS C$,8 AS D$,16 AS E$,8 AS F$,19 AS G$,2 AS H$
1500 FOR I%=1 TO OLEN#
1510 LSET A$=ESP$:RSET B$=ESP$:RSET C$=ESP$:RSET D$=ESP$:LSET E$=SPACE$(16):RSET F$=ESP$:LSET G$=SPACE$(19):LSET H$=TRM$:PUT #2,I%
1520 NEXT I%
1530 CLOSE #2:OLEN$=PADL$(OLEN$,5," "):OLEN$=RIGHT$(OLEN$,5):RETURN
1540 INPUT "Enter Table Size",QLEN$:LEN$=QLEN$:GOSUB 1890:GOSUB 1940:PRINT "FREE MEMORY ";MEM$:SLEEP 1000
1550 IF BAD%=1 THEN PRINT DISP$:SLEEP 2000:GOTO 1540
1560 KILL "QUICK.DAT":PRINT "Initializing... "
1570 OPEN "QUICK.DAT" FOR RANDOM AS #1 LEN = 13
1580 FIELD #1, 3 AS QID$, 8 AS QTR$, 2 AS LFCR$
1590 FOR I% = 1 TO QLEN#
1600 LSET QID$=TSP$:RSET QTR$=ESP$:LSET LFCR$=TRM$:PUT #1, I%
1610 NEXT I%
1620 CLOSE #1:QLEN$=PADL$(QLEN$,5," "):QLEN$=RIGHT$(QLEN$,5):RETURN
1630 INPUT "Enter Table Size",PLEN$:LEN$=PLEN$:GOSUB 1890:GOSUB 1940:PRINT "FREE MEMORY ";MEM$:SLEEP 1000
1640 IF BAD%=1 THEN PRINT DISP$:SLEEP 2000:GOTO 1630
1650 KILL "PERM.DAT":PRINT "Initializing... "
1660 OPEN "PERM.DAT" FOR RANDOM AS #2 LEN = 29
1670 FIELD #2,8 AS PID$,8 AS PTWT$,8 AS ACC$,3 AS PLD$,2 AS LFCR$
1680 FOR I%=1 TO PLEN#
1690 LSET PID$=ESP$:RSET PTWT$=ESP$:RSET ACC$=ESP$:RSET PLD$=TSP$:LSET LFCR$=TRM$:PUT #2,I%
1700 NEXT I%
1710 CLOSE #2:PLEN$=PADL$(PLEN$,5," "):PLEN$=RIGHT$(PLEN$,5):RETURN
1720 INPUT "Enter Table Size",CLEN$:LEN$=CLEN$:GOSUB 1890:GOSUB 1940:PRINT "FREE MEMORY ";MEM$:SLEEP 1000
1730 IF BAD%=1 THEN PRINT DISP$:SLEEP 2000:GOTO 1720
1740 KILL "COMOD.DAT":PRINT "Initializing... "
1750 OPEN "COMOD.DAT" FOR RANDOM AS #3 LEN = 46
1760 FIELD #3,16 AS CA$,8 AS CB$,11 AS CC$,3 AS CD$,6 AS CE$,2 AS LFCR$
1770 LSET CA$="NONE            ":RSET CB$="       1":RSET CC$=SPACE$(11):RSET CD$=TSP$:LSET CE$=SSP$:LSET LFCR$=TRM$:PUT #3, 1
1780 FOR I% = 2 TO CLEN#
1790 LSET CA$=SPACE$(16):RSET CB$=ESP$:RSET CC$=SPACE$(11):RSET CD$=TSP$:LSET CE$=SSP$:LSET LFCR$=TRM$:PUT #3, I%
1800 NEXT I%
1810 CLOSE #3:CLEN$=PADL$(CLEN$,5," "):CLEN$=RIGHT$(CLEN$,5):RETURN
1820 KILL "BADGE.DAT":PRINT "Initializing... "
1830 OPEN "BADGE.DAT" FOR RANDOM AS #1 LEN=46
1840 FIELD #1,20 AS BDG$,8 AS BID$,16 AS BDGNM$,2 AS LFCR$
1850 FOR I%=1 TO 100
1860 LSET BID$=ESP$:RSET BDG$=SPACE$(20):LSET LFCR$=TRM$:PUT #1,I%
1870 NEXT I%
1880 CLOSE #1:RETURN
1890 BAD%=0
1900 FOR L%=1 TO LEN(LEN$)
1910 IF MID$(LEN$,L%,1)<CHR$(48) OR MID$(LEN$,L%,1)>CHR$(57) THEN BAD%=1
1920 NEXT L%
1930 IF BAD%=1 THEN DISP$=" Re-Enter Size":RETURN
1940 PLEN#=VAL(PLEN$):PMEM#=PLEN#*29:ILEN#=VAL(ILEN$):IMEM#=ILEN#*36:OLEN#=VAL(OLEN$):OMEM#=OLEN#*77:CLEN#=VAL(CLEN$):CMEM#=CLEN#*43
1950 QLEN#=VAL(QLEN$):QMEM#=QLEN#*13:MEMTOT#=PMEM#+IMEM#+OMEM#+CMEM#+QMEM#
1960 IF MEMTOT#>50000 THEN DISP$="Tables Too Large":BAD%=1:RETURN
1970 FREEM#=(50000 - MEMTOT#)/500:FREEM#=CINT(FREEM#):FM$=STR$(FREEM#):MEM$=FM$+"%":RETURN
1980 OPEN "INBOUND.DAT" FOR RANDOM AS #1 LEN=36
1990 FIELD #1, 8 AS REC_ID$, 8 AS IN_WT$, 8 AS IN_T$, 10 AS IN_D$, 2 AS LFCR$
2000 PRINT "Clearing..."
2010 FOR I%=1 TO ILEN#
2020 LSET REC_ID$=ESP$:RSET IN_WT$=ESP$:RSET IN_T$=ESP$:RSET IN_D$=SPACE$(10):LSET LFCR$=TRM$:PUT #1,I%
2030 NEXT I%
2040 CLOSE #1
2050 OPEN "quick" FOR RANDOM AS #2 LEN=13
2060 FIELD #2, 3 AS QID$, 8 AS QTR$, 2 AS LFCR$
2070 FOR I% = 1 TO QLEN#
2080 LSET QID$=TSP$:RSET QTR$=ESP$:LSET LFCR$=TRM$
2090 PUT #2,I%
2100 NEXT I%
2110 CLOSE #2:RETURN
2120 OPEN "OUTBOUND.DAT" FOR RANDOM AS #2 LEN = 77
2130 FIELD #2,8 AS A$,8 AS B$,8 AS C$,8 AS D$,16 AS E$,8 AS F$,19 AS G$,2 AS H$
2140 PRINT "Clearing... "
2150 FOR I%=1 TO OLEN#
2160 LSET A$=ESP$:RSET B$=ESP$:RSET C$=ESP$:RSET D$=ESP$:LSET E$=SPACE$(16):RSET F$=ESP$:LSET G$=SPACE$(19):LSET H$=TRM$
2170 PUT #2,I%
2180 NEXT I%
2190 CLOSE #2:RETURN
2200 OPEN "PERM.DAT" FOR RANDOM AS #2 LEN = 29
2210 FIELD #2,8 AS PID$,8 AS PTWT$,8 AS ACC$,3 AS PLD$,2 AS LFCR$
2220 IF RSTF%<>1 THEN PRINT "Clearing..."
2230 FOR I% = 1 TO PLEN#
2240 GET #2, I%
2250 IF PID$<>"        " THEN RSET ACC$="       0":RSET PLD$="  0"
2260 PUT #2,I%
2270 NEXT I%
2280 CLOSE #2:RETURN
2290 OPEN "COMOD.DAT" FOR RANDOM AS #3 LEN = 46
2300 FIELD #3,16 AS CA$,8 AS CB$,11 AS CC$,3 AS CD$,6 AS CE$,2 AS LFCR$
2310 IF RSTF%<>1 THEN PRINT "Clearing..."
2320 FOR I% = 1 TO CLEN#
2330 GET #3, I%
2340 IF CA$<>"                " THEN RSET CC$="          0":RSET CD$="  0"
2350 PUT #3, I%
2360 NEXT I%
2370 CLOSE #3:SLEEP 1000:RETURN
2380 INPUT "    ENTER ID",ID$
2390 IF LEN(ID$) < 1 OR LEN(ID$) > 8 THEN PRINT "   Invalid ID":SLEEP 2000:RETURN
2400 ID$=PADR$(ID$,8," "):F%=0:PRINT "Searching..."
2410 OPEN "INBOUND.DAT" FOR RANDOM AS #1 LEN=36
2420 FIELD #1, 8 AS REC_ID$, 8 AS IN_WT$, 8 AS IN_T$, 10 AS IN_D$, 2 AS LFCR$
2430 FOR I%=1 TO ILEN#
2440 GET #1, I%
2450 IF REC_ID$ = ID$ THEN F%=1:J%=I%:I%=ILEN#
2460 NEXT I%
2470 IF F%=1 THEN LSET REC_ID$=ESP$:RSET IN_WT$=ESP$:RSET IN_T$=ESP$:RSET IN_D$=SPACE$(10):PUT #1, J%:PRINT " Record deleted":SLEEP 1500:CLOSE #1
2480 IF F%=0 THEN PRINT "Record not found":SLEEP 1500:CLOSE #1
2490 S$="N":INPUT "^DELETE MORE?   ^N,Y",S$
2500 IF S$="Y" THEN GOTO 2380 ELSE RETURN
2510 INPUT "    ENTER ID",ID$
2520 IF LEN(ID$) < 1 OR LEN(ID$) > 3 THEN PRINT "Invalid ID":SLEEP 2000:RETURN
2530 ID$=PADR$(ID$,3," "):F%=0:PRINT "Searching..."
2540 OPEN "QUICK.DAT" FOR RANDOM AS #1 LEN = 13
2550 FIELD #1, 3 AS QID$, 8 AS QTR$, 2 AS LFCR$
2560 FOR I% = 1 TO QLEN#
2570 GET #1, I%
2580 IF QID$ = ID$ THEN F%=1:J%=I%:I%=QLEN#
2590 NEXT I%
2600 IF F%=1 THEN LSET QID$=ESP$:RSET QTR$=SSP$:PUT #1,J%:CLOSE #1:PRINT "Record Deleted":SLEEP 2000
2610 IF F%=0 THEN PRINT "Record Not Found":SLEEP 2000:CLOSE #1
2620 S$="N":INPUT "^DELETE MORE?   ^N,Y",S$
2630 IF S$="Y" THEN GOTO 2510 ELSE RETURN
2640 INPUT "    ENTER ID",ID$
2650 IF LEN(ID$) < 1 OR LEN(ID$) > 8 OR ASC(ID$)<65 OR ASC(ID$)>90 THEN PRINT "Invalid ID":SLEEP 2000:GOTO 2640
2660 ID$=PADR$(ID$,8," "):F%=0:PRINT "Searching..."
2670 OPEN "PERM.DAT" FOR RANDOM AS #1 LEN=29
2680 FIELD #1,8 AS PID$,8 AS PTWT$,8 AS ACC$,3 AS PLD$,2 AS LFCR$
2690 FOR I% = 1 TO PLEN#
2700 GET #1, I%
2710 IF PID$ = ID$ THEN F%=1:I%=PLEN#
2720 NEXT I%
2730 IF F%=1 THEN PRINT "    ID Exist":CLOSE #1:SLEEP 2000:GOTO 2640
2740 F%=0
2750 FOR I% = 1 TO PLEN#
2760 GET #1, I%
2770 IF PID$ = ESP$ THEN F% = 1:J%=I%:I%=PLEN#
2780 NEXT I%
2790 IF F% = 1 THEN GOTO 2800 ELSE PRINT "   Table Full":SLEEP 3000:CLOSE #1:RETURN
2800 S$="N"
2810 IF G1#>2000 THEN INPUT "^TARE ON SCL A? ^N,Y",S$
2820 IF S$="Y" THEN TWT$=STR$(G1#):TWT$=LTRIM$(TWT$):GOTO 2870
2830 S$="N"
2840 IF G2#>2000 THEN INPUT "^TARE ON SCL B? ^N,Y",S$
2850 IF S$="Y" THEN TWT$=STR$(G2#):TWT$=LTRIM$(TWT$):GOTO 2870
2860 INPUT " ENTER TARE WT",TWT$
2870 VAL%=0
2880 IF LEN(TWT$) < 1 OR LEN(TWT$) > 8 THEN VAL%=1
2890 FOR K% = 1 TO LEN(TWT$)
2900 K$=MID$(TWT$,K%,1): IF ASC(K$)<46 OR ASC(K$)>57 OR ASC(K$)=47 THEN VAL%=1
2910 NEXT K%
2920 IF VAL%=1 THEN PRINT "Invalid Tare WT":SLEEP 2000:GOTO 2800
2930 TWT$=PADL$(TWT$,8," "):RSET PID$ = ID$:RSET ACC$ = "       0":RSET PLD$ = "  0":RSET PTWT$=TWT$:PUT #1,J%:CLOSE #1
2940 S$="N":INPUT "^ADD MORE?      ^N,Y",S$
2950 IF S$="Y" THEN GOTO 2640 ELSE RETURN
2960 INPUT "    ENTER ID",ID$
2970 IF LEN(ID$) < 1 OR LEN(ID$) > 8 THEN PRINT "  Invalid Name":SLEEP 2000:GOTO 3140
2980 ID$=PADR$(ID$,8," ")
2990 OPEN "PERM.DAT" FOR RANDOM AS #3 LEN=29
3000 FIELD #3,8 AS PID$,8 AS PTWT$,8 AS ACC$,3 AS PLD$,2 AS LFCR$
3010 F%=0:PRINT "Searching..."
3020 FOR I% = 1 TO PLEN#
3030 GET #3, I%: IF ID$=PID$ THEN F%=1:J%=I%:I%=PLEN#
3040 NEXT I%
3050 IF F%=0 THEN PRINT " Does not exist":SLEEP 2000:CLOSE #3:GOTO 3140
3060 INPUT " ENTER TARE WT",NPTWT$
3070 VAL%=0
3080 IF LEN(NPTWT$) < 1 OR LEN(NPTWT$) > 8 THEN PRINT "  Invalid Tare":SLEEP 2000:VAL%=1
3090 FOR K% = 1 TO LEN(NPTWT$)
3100 K$=MID$(NPTWT$,K%,1): IF ASC(K$)<46 OR ASC(K$)>57 OR ASC(K$)=47 THEN VAL%=1
3110 NEXT K%
3120 IF VAL%=1 THEN PRINT "Invalid Tare WT":SLEEP 2000:CLOSE #3:GOTO 3140
3130 NPTWT$=PADL$(NPTWT$,8," "):LSET PTWT$=NPTWT$:PUT #3,J%:CLOSE #3
3140 :
3150 S$="N":INPUT "^EDIT MORE?     ^N,Y",S$
3160 IF S$="Y" THEN GOTO 2960 ELSE RETURN
3170 INPUT "    ENTER ID",ID$
3180 IF LEN(ID$) < 1 OR LEN(ID$) > 8 OR ASC(ID$)<65 OR ASC(ID$)>90 THEN PRINT "Invalid ID":SLEEP 2000:RETURN
3190 ID$=PADR$(ID$,8," "):F%=0:PRINT "Searching..."
3200 OPEN "PERM.DAT" FOR RANDOM AS #1 LEN=29
3210 FIELD #1,8 AS PID$,8 AS PTWT$,8 AS ACC$,3 AS PLD$,2 AS LFCR$
3220 FOR I% = 1 TO PLEN#
3230 GET #1, I%: IF PID$ = ID$ THEN F%=1:J%=I%:I%=PLEN#
3240 NEXT I%
3250 IF F%=1 THEN LSET PID$=ESP$:RSET PTWT$=SSP$:RSET ACC$=ESP$:RSET PLD$=TSP$:PUT #1,J%:CLOSE #1:PRINT "Record Deleted":SLEEP 2000
3260 IF F%=0 THEN PRINT "Record Not Found":SLEEP 2000:CLOSE #1
3270 S$="N":INPUT "^DELETE MORE?   ^N,Y",S$
3280 IF S$="Y" THEN GOTO 3170 ELSE RETURN
3290 S$="N":INPUT "^OPERATOR?      ^N,Y",S$
3300 IF S$="N" THEN GOTO 3360
3310 INPUT "  NEW PASSWORD",EPW$
3320 INPUT "CONFIRM PASSWORD",CPW$
3330 IF EPW$<>CPW$ THEN PRINT "INVALID PASSWORD":SLEEP 2000:GOTO 3290
3340 IF LEN(EPW$)>8 THEN PRINT "INVALID PASSWORD":SLEEP 2000:GOTO 3290
3350 OPASS$=EPW$:S$="N"
3360 S$="N":INPUT "^SUPERVISOR?    ^N,Y",S$
3370 IF S$="N" THEN RETURN
3380 INPUT "  NEW PASSWORD",EPW$
3390 INPUT "CONFIRM PASSWORD",CPW$
3400 IF EPW$<>CPW$ THEN PRINT "INVALID PASSWORD":SLEEP 2000:GOTO 3360
3410 IF LEN(EPW$)>8 THEN PRINT "INVALID PASSWORD":SLEEP 2000:GOTO 3360
3420 SPASS$=EPW$:S$="N":RETURN
3430 INPUT "^ENABLE COMNTS? ^N,Y",CMNT$
3440 IF CMNT$="N" THEN RETURN
3450 INPUT "ENTER QTY 1 TO 5",CQ$:PMT1$="":PMT2$="":PMT3$="":PMT4$="":PMT5$=""
3460 IF ASC(CQ$)<49 OR ASC(CQ$)>53 OR LEN(CQ$)<>1 THEN PRINT " Invalid Qty":SLEEP 1000:GOTO 3430
3470 INPUT "ENTER 1st PROMPT",PMT1$:PMT1$=PADR$(PMT1$,16," "):PMT1$=RIGHT$(PMT1$,16)
3480 IF VAL(CQ$)>1 THEN INPUT "ENTER 2nd PROMPT",PMT2$:PMT2$=PADR$(PMT2$,16," "):PMT2$=RIGHT$(PMT2$,16)
3490 IF VAL(CQ$)>2 THEN INPUT "ENTER 3rd PROMPT",PMT3$:PMT3$=PADR$(PMT3$,16," "):PMT3$=RIGHT$(PMT3$,16)
3500 IF VAL(CQ$)>3 THEN INPUT "ENTER 4th PROMPT",PMT4$:PMT4$=PADR$(PMT4$,16," "):PMT4$=RIGHT$(PMT4$,16)
3510 IF VAL(CQ$)>4 THEN INPUT "ENTER 5th PROMPT",PMT5$:PMT5$=PADR$(PMT5$,16," "):PMT5$=RIGHT$(PMT5$,16)
3520 OPEN "PROMPT.DAT" FOR RANDOM AS #2 LEN = 82
3530 FIELD #2,16 AS SPMT1$,16 AS SPMT2$,16 AS SPMT3$,16 AS SPMT4$,16 AS SPMT5$,2 AS LFCR$
3540 LSET SPMT1$=PMT1$:LSET SPMT2$=PMT2$:LSET SPMT3$=PMT3$:LSET SPMT4$=PMT4$:LSET SPMT5$=PMT5$:LSET LFCR$=TRM$
3550 PUT #2,1:CLOSE #2
3560 RETURN
3570 INPUT "   ENTER NAME",CMDNAME$:CMDNAME$=UCASE$(CMDNAME$)
3580 IF LEN(CMDNAME$) < 1 OR LEN(CMDNAME$) > 16 THEN PRINT "  Invalid Name":SLEEP 2000:RETURN
3590 CMDNAME$=PADR$(CMDNAME$,16," ")
3600 OPEN "COMOD.DAT" FOR RANDOM AS #1 LEN = 46
3610 FIELD #1,16 AS CA$,8 AS CB$,11 AS CC$,3 AS CD$,6 AS CE$,2 AS LFCR$
3620 F%=0
3630 FOR I% = 1 TO CLEN#
3640 GET #1, I%: PRINT "Searching..."
3650 IF CA$ = CMDNAME$ THEN F%=1:I%=CLEN#
3660 NEXT I%
3670 IF F%=1 THEN PRINT "Commodity exists":CLOSE #1:SLEEP 2000:GOTO 3570
3680 FOR I% = 1 TO CLEN#
3690 GET #1,I%: IF CA$ = "                " THEN F% = 1:J%=I%:I%=CLEN#
3700 NEXT I%
3710 IF F% = 0 THEN PRINT "   Table Full":SLEEP 3000:CLOSE #1:RETURN
3720 LSET CA$ = CMDNAME$
3730 INPUT "  ENTER FACTOR",CFACT$
3740 IF LEN(CFACT$) < 1 OR LEN(CFACT$) > 8 THEN PRINT " Invalid factor":SLEEP 2000:GOTO 3730
3750 VAL%=0
3760 FOR K% = 1 TO LEN(CFACT$)
3770 K$=MID$(CFACT$,K%,1): IF ASC(K$)<46 OR ASC(K$)>57 OR ASC(K$)=47 THEN VAL%=1
3780 NEXT K%
3790 IF VAL%=1 THEN PRINT " Invalid Factor":SLEEP 2000:GOTO 3730
3800 RSET CB$=CFACT$
3810 :
3820 INPUT "   ENTER UNITS",UNIT$
3830 IF LEN(UNIT$) < 1 OR LEN(UNIT$) > 6 THEN PRINT "  Invalid Units":SLEEP 2000:GOTO 3810
3840 LSET CE$=UNIT$
3850 PUT #1,J%:CLOSE #1
3860 S$="N":INPUT "^ENTER ANOTHER? ^N,Y",S$
3870 IF S$="Y" THEN GOTO 3570
3880 RETURN
3890 INPUT "   ENTER NAME",CMDNAME$:CMDNAME$=UCASE$(CMDNAME$)
3900 IF LEN(CMDNAME$) < 1 OR LEN(CMDNAME$) > 16 THEN PRINT "  Invalid Name":SLEEP 2000:GOTO 3890
3910 CMDNAME$=PADR$(CMDNAME$,16," ")
3920 OPEN "COMOD.DAT" FOR RANDOM AS #3 LEN = 46
3930 FIELD #3,16 AS CA$,8 AS CB$,11 AS CC$,3 AS CD$,6 AS CE$,2 AS LFCR$
3940 F%=0
3950 FOR I% = 1 TO CLEN#
3960 GET #3, I%: PRINT "Searching..."
3970 IF CA$ = CMDNAME$ THEN F%=1:J% = I%: I%=CLEN#
3980 NEXT I%
3990 IF F%=0 THEN PRINT " Does not exist":SLEEP 2000:CLOSE #3:GOTO 3890
4000 IF F%=1 THEN INPUT "ENTER NEW FACTOR",CFACT$
4010 IF VAL(CFACT$) < 0 THEN PRINT "Invalid Factor":SLEEP 2000:GOTO 3990
4020 VAL%=0
4030 FOR K% = 1 TO LEN(CFACT$)
4040 K$=MID$(CFACT$,K%,1)
4050 IF ASC(K$)<46 OR ASC(K$)>57 OR ASC(K$)=47 THEN VAL%=1
4060 NEXT K%
4070 IF VAL%=1 THEN PRINT " Invalid Factor":SLEEP 2000:GOTO 3990
4080 RSET CB$=CFACT$:PUT #3,J%:CLOSE #3
4090 S$="N":INPUT "^EDIT ANOTHER?  ^N,Y",S$
4100 IF S$="Y" THEN GOTO 3890
4110 RETURN
4120 INPUT "   ENTER NAME",CMDNAME$:CMDNAME$=UCASE$(CMDNAME$)
4130 IF LEN(CMDNAME$) < 1 OR LEN(CMDNAME$) > 16 THEN PRINT "  Invalid Name":SLEEP 2000:GOTO 4120
4140 CMDNAME$=PADR$(CMDNAME$,16," ")
4150 OPEN "COMOD.DAT" FOR RANDOM AS #3 LEN = 46
4160 FIELD #3,16 AS CA$,8 AS CB$,11 AS CC$,3 AS CD$,6 AS CE$,2 AS LFCR$
4170 F%=0
4180 FOR I% = 1 TO CLEN#
4190 GET #3, I%: PRINT "Searching..."
4200 IF CA$ = CMDNAME$ THEN F%=1:J% = I%: I%=CLEN#
4210 NEXT I%
4220 IF F%=0 THEN PRINT " Does not exist":SLEEP 2000:CLOSE #3:GOTO 4120
4230 LSET CA$=SPACE$(16):RSET CB$=ESP$:RSET CC$=SPACE$(11):RSET CD$=TSP$:LSET CE$=ESP$:LSET LFCR$=TRM$
4240 PRINT "    Deleted":SLEEP 1000:PUT #3,J%:CLOSE #3
4250 S$="N":INPUT "^DELETE ANOTHER?^N,Y",S$
4260 IF S$="Y" THEN GOTO 4120
4270 RETURN
4280 OPEN "COMOD.DAT" FOR RANDOM AS #1 LEN = 46
4290 FIELD #1,16 AS CA$,8 AS CB$,11 AS CC$,3 AS CD$,6 AS CE$,2 AS LFCR$
4300 INDEXED #1,CA$:PRINT "Sorting...":SORTREC #1,CA$:CLOSE #1:RETURN
4310 INPUT "    ENTER ID",ID$
4320 IF LEN(ID$) < 1 OR LEN(ID$) > 3 THEN PRINT "   Invalid ID":SLEEP 2000:GOTO 4310
4330 ID$=PADR$(ID$,3," ")
4340 OPEN "QUICK.DAT" FOR RANDOM AS #1 LEN = 13
4350 FIELD #1, 3 AS QID$,8 AS QTR$,2 AS LFCR$
4360 F%=0
4370 FOR I% = 1 TO QLEN#
4380 GET #1, I%: PRINT "Searching..."
4390 IF QID$ = ID$ THEN F%=1: J%=I%:I%=QLEN#
4400 NEXT I%
4410 IF F%=0 THEN PRINT "Record not found":SLEEP 2000:CLOSE #1:RETURN
4420 LSET QID$=TSP$:RSET QTR$=ESP$:CLOSE #1
4430 PRINT " Record deleted":SLEEP 2000:RETURN
4440 BADGE$=""
4450 PRINT "   SWIPE CARD"
4460 OPEN "COM1: TMO10000 TRM13" FOR INPUT AS #5
4470 FLUSH #5:INPUT #5,SWP$
4480 BADGE$=LTRIM$(SWP$):BADGE$=RTRIM$(BADGE$):CLOSE #5
4490 IF BADGE$="" THEN PRINT "INVALID BADGE":SLEEP 2000:GOTO 4760
4500 BADGE$=LEFT$(BADGE$,LEN(BADGE$)-1):BADGE$=PADR$(BADGE$,20," ")
4510 F%=0:PRINT "Searching..."
4520 OPEN "BADGE.DAT" FOR RANDOM AS #1 LEN=46
4530 FIELD #1,20 AS BDG$,8 AS BID$,16 AS BDGNM$,2 AS LFCR$
4540 FOR I% = 1 TO 100
4550 GET #1, I%: IF BADGE$ = BDG$ THEN F%=1:I%=100
4560 NEXT I%
4570 IF F%=1 THEN PRINT "  BADGE EXIST":CLOSE #1:SLEEP 2000:GOTO 4760
4580 INPUT "    ENTER ID",ID$:ID$=UCASE$(ID$)
4590 IF LEN(ID$) < 1 OR LEN(ID$) > 8 OR ASC(ID$)<48 OR ASC(ID$)>122 THEN PRINT "Invalid ID":SLEEP 2000:GOTO 4580
4600 ID$=PADR$(ID$,8," "):F%=0:PRINT "Searching..."
4610 FOR I% = 1 TO 100
4620 GET #1, I%
4630 IF BID$ = ID$ THEN F%=1:I%=100
4640 NEXT I%
4650 IF F%=1 THEN PRINT "    ID EXIST":SLEEP 2000:GOTO 4580
4660 F%=0
4670 FOR I% = 1 TO 100
4680 GET #1, I%
4690 IF BID$ = ESP$ THEN F% = 1:J%=I%:I%=100
4700 NEXT I%
4710 IF F% = 1 THEN GOTO 4720 ELSE PRINT "   Table Full":SLEEP 3000:CLOSE #1:RETURN
4720 INPUT "ENTER USER NAME",BDGNAME$:BDGNAME$=UCASE$(BDGNAME$)
4730 IF LEN(BDGNAME$) < 1 OR LEN(BDGNAME$) > 16 THEN PRINT "  Invalid Name":SLEEP 2000:GOTO 4720
4740 BDGNAME$=PADR$(BDGNAME$,16," ")
4750 RSET BDG$=BADGE$:RSET BID$=ID$:RSET BDGNM$=BDGNAME$:PUT #1,J%:CLOSE #1
4760 S$="N":INPUT "^ADD MORE?      ^N,Y",S$
4770 IF S$="Y" THEN GOTO 4440 ELSE RETURN
4780 INPUT "    ENTER ID",ID$:ID$=UCASE$(ID$)
4790 IF LEN(ID$) < 1 OR LEN(ID$) > 8 OR ASC(ID$)<48 OR ASC(ID$)>122 THEN PRINT "Invalid ID":SLEEP 2000:GOTO 4780
4800 ID$=PADR$(ID$,8," "):F%=0:PRINT "Searching..."
4810 OPEN "BADGE.DAT" FOR RANDOM AS #1 LEN=46
4820 FIELD #1,20 AS BDG$,8 AS BID$,16 AS BDGNM$,2 AS LFCR$
4830 FOR I% = 1 TO 100
4840 GET #1, I%
4850 IF BID$ = ID$ THEN F%=1:J%=I%:I%=100
4860 NEXT I%
4870 IF F%=1 THEN LSET BID$=ESP$:RSET BDG$=SPACE$(20):LSET BDGNM$=SPACE$(16):PUT #1,J%:CLOSE #1:PRINT "BADGE DELETED":SLEEP 2000
4880 IF F%=0 THEN PRINT "BADGE NOT FOUND":SLEEP 2000:CLOSE #1
4890 S$="N":INPUT "^DELETE MORE?   ^N,Y",S$
4900 IF S$="Y" THEN GOTO 4780 ELSE RETURN
4910 VAL%=0
4920 INPUT "HOUR?         ",HR$:HR$=RIGHT$(HR$,2):INPUT "MINUTES?      ",MN$:MN$=RIGHT$(MN$,2):INPUT "SECONDS?      ",SC$:SC$=RIGHT$(SC$,2)
4930 INPUT "DAY?          ",DY$:DY$=RIGHT$(DY$,2):INPUT "MONTH?        ",MO$:MO$=RIGHT$(MO$,2):INPUT "YEAR?         ",YR$:YR$=RIGHT$(YR$,2):YR$="20"+YR$
4940 IF VAL(HR$)>23 OR VAL(HR$)<0 OR VAL(MN$)>59 OR VAL(MN$)<0 OR VAL(SC$)>59 OR VAL(SC$)<0 THEN VAL%=1
4950 IF VAL(MO$)>12 OR VAL(MO$)<1 OR VAL(DY$)>31 OR VAL(DY$)<1 OR VAL(YR$)>2099 OR VAL(YR$)<2000 THEN VAL%=1
4960 IF VAL(YR$) MOD 4=0 THEN LPY%=1 ELSE LPY%=0
4970 IF LYP%=1 AND VAL(DY$)>29 AND VAL(MO$)=2 THEN VAL%=1
4980 IF LYP%=0 AND VAL(DY$)>28 AND VAL(MO$)=2 THEN VAL%=1
4990 IF (VAL(MO$)=4 OR VAL(MO$)=6 OR VAL(MO$)=9 OR VAL(MO$)=11) AND VAL(DY$)>30 THEN VAL%=1
5000 IF VAL%=1 THEN PRINT " INVALID ENTRY!":SLEEP 2000:GOTO 4910
5010 NEWT$=HR$+":"+MN$+":"+SC$:NEWD$=MO$+"-"+DY$+"-"+YR$:TIME$=NEWT$:DATE$=NEWD$:RETURN
5020 GOSUB 1940
5030 OPEN "com2:tmo5000" FOR OUTPUT AS #4:FLUSH #4
5040 PRINT #4,"METTLER-TOLEDO SOFTWARE VSX  REV.  4.0.0"+TRM$;
5050 PRINT #4,"========================================"+TRM$
5060 PRINT #4,"INBOUND TABLE SIZE  "+ILEN$+TRM$;
5070 PRINT #4,"QUICK TABLE SIZE    "+QLEN$+TRM$;
5080 PRINT #4,"OUTBOUND TABLE SIZE "+OLEN$+TRM$;
5090 PRINT #4,"PERMANENT TABLE SIZE"+PLEN$+TRM$;
5100 PRINT #4,"COMMODITY TABLE SIZE"+CLEN$+TRM$;
5110 PRINT #4,"AVAILABLE MEMORY     "+MEM$+TRM$;
5120 PRINT #4,"COMMODITIES ENABLED   "+COMDTY$+TRM$;
5130 PRINT #4,"BADGE ENABLED         "+EBDG$+TRM$;
5140 PRINT #4,"COMMENTS ENABLED      "+CMNT$+TRM$;
5150 PRINT #4,"NUMBER OF COMMENTS    "+CQ$+TRM$;
5160 PRINT #4,"PROMPT 1              "+PMT1$+TRM$;
5170 PRINT #4,"PROMPT 2              "+PMT2$+TRM$;
5180 PRINT #4,"PROMPT 3              "+PMT3$+TRM$;
5190 PRINT #4,"PROMPT 4              "+PMT4$+TRM$;
5200 PRINT #4,"PROMPT 5              "+PMT5$+TRM$;
5210 PRINT #4,"LOOPS ENABLED         "+LPC$+TRM$;
5220 PRINT #4,"HOST ENABLED          "+HOST$+TRM$;
5230 PRINT #4,"HOST IP ADDRESS       "+IP$+TRM$
5240 CLOSE #4:CLOSE #1:RETURN
5250 PRINT "PLEASE WAIT..."
5260 OPEN "SETUP.DAT" FOR RANDOM AS #1 LEN = 52
5270 FIELD #1,5 AS SIL$,5 AS SOL$,5 AS SQL$,5 AS SPL$,5 AS SCL$,4 AS SSCLT$,1 AS SLPC$,1 AS SH$,15 AS SIP$,4 AS SPORT$,2 AS LFCR$
5280 LSET SIL$=ILEN$:LSET SOL$=OLEN$:LSET SQL$=QLEN$:LSET SPL$=PLEN$:LSET SCL$=CLEN$:LSET SSCLT$=SCLT$:LSET SLPC$=LPC$
5290 LSET SH$=HOST$:LSET SIP$=IP$:LSET SPORT$=PORT$
5300 PUT #1,1:CLOSE #1
5310 RETURN
5320 OPEN "INBOUND.DAT" FOR RANDOM AS #1 LEN=36
5330 FIELD #1, 8 AS REC_ID$, 8 AS IN_WT$, 8 AS IN_T$, 10 AS IN_D$, 2 AS LFCR$
5340 ASS$="0"
5350 FOR I%=1 TO 100
5360 PRINT "   RESETTING"
5370 RSET REC_ID$=ESP$:RSET IN_WT$=ESP$:RSET IN_T$=ESP$:RSET IN_D$=SPACE$(10):RSET LFCR$=TRM$
5380 PUT #1,I%
5390 NEXT I%
5400 CLOSE #1:ILEN#=100:ILEN$="100"
5410 OPEN "PERM.DAT" FOR RANDOM AS #1 LEN=29
5420 FIELD #1,8 AS PID$,8 AS PTWT$,8 AS ACC$,3 AS PLD$,2 AS LFCR$
5430 FOR I%=1 TO 100
5440 PRINT "  TO FACTORY!"
5450 RSET PID$=ESP$:RSET PTWT$=ESP$:RSET ACC$=ESP$:RSET PLD$=TSP$:RSET LFCR$=TRM$
5460 PUT #1,I%
5470 NEXT I%
5480 CLOSE #1:PLEN#=100:PLEN$="100"
5490 OPEN "OUTBOUND.DAT" FOR RANDOM AS #1 LEN=77
5500 FIELD #1,8 AS A$,8 AS B$,8 AS C$,8 AS D$,16 AS E$,8 AS F$,19 AS G$,2 AS H$
5510 FOR I%=1 TO 100
5520 PRINT "   RESETTING"
5530 RSET A$=ESP$:RSET B$=ESP$:RSET C$=ESP$:RSET D$=ESP$:RSET E$=SPACE$(16):RSET F$=ESP$:RSET G$=SPACE$(19):RSET H$=TRM$
5540 PUT #1,I%
5550 NEXT I%
5560 CLOSE #1:OLEN#=100:OLEN$="100"
5570 OPEN "COMOD.DAT" FOR RANDOM AS #1 LEN=46
5580 FIELD #1,16 AS CA$,8 AS CB$,11 AS CC$,3 AS CD$,6 AS CE$,2 AS LFCR$
5590 RSET CA$="NONE            ":RSET CB$="       1":RSET CC$=SPACE$(11):RSET CD$=TSP$:RSET CE$=SSP$:RSET LFCR$=TRM$:PUT #1,1
5600 FOR I%=2 TO 10
5610 RSET CA$=SPACE$(16):RSET CB$=ESP$:RSET CC$=SPACE$(11):RSET CD$=TSP$:RSET CE$=SSP$:RSET LFCR$=TRM$
5620 PUT #1,I%
5630 NEXT I%
5640 CLOSE #1:CLEN#=10:CLEN$="10"
5650 OPEN "QUICK.DAT" FOR RANDOM AS #1 LEN=13
5660 FIELD #1, 3 AS QID$, 8 AS QTR$, 2 AS LFCR$
5670 PRINT "  TO FACTORY!"
5680 FOR I%=1 TO 100
5690 RSET QID$=TSP$:RSET QTR$=ESP$:RSET LFCR$=TRM$
5700 PUT #1,I%
5710 NEXT I%
5720 CLOSE #1:QLEN#=100:QLEN$="100"
5730 OPEN "BADGE.DAT" FOR RANDOM AS #1 LEN=46
5740 FIELD #1,20 AS BDG$,8 AS BID$,16 AS BDGNM$,2 AS LFCR$
5750 PRINT "  PLEASE WAIT"
5760 FOR I%=1 TO 100
5770 RSET BDG$=SPACE$(20):LSET BID$=ESP$:LSET BDGNM$=SPACE$(16):LSET LFCR$=TRM$:PUT #1,I%
5780 NEXT I%
5790 CLOSE #1
5800 OPEN "SETUP.DAT" FOR RANDOM AS #1 LEN = 52
5810 FIELD #1,5 AS SIL$,5 AS SOL$,5 AS SQL$,5 AS SPL$,5 AS SCL$,4 AS SSCLT$,1 AS SLPC$,1 AS SH$,15 AS SIP$,4 AS SPORT$,2 AS LFCR$
5820 LSET SIL$="  100":LSET SOL$="  100":LSET SQL$="  100":LSET SPL$="  100":LSET SCL$="   10":LSET SSCLT$="PLAT":LSET SLPC$="N"
5830 LSET SH$=HOST$:LSET SIP$="111.111.111.111":LSET SPORT$="1920"
5840 PUT #1,1:CLOSE #1
5850 OPEN "PROMPT.DAT" FOR RANDOM AS #1 LEN = 82
5860 FIELD #1,16 AS SPMT1$,16 AS SPMT2$,16 AS SPMT3$,16 AS SPMT4$,16 AS SPMT5$,2 AS LFCR$
5870 LSET SPMT1$=SPACE$(16):LSET SPMT2$=SPACE$(16):LSET SPMT3$=SPACE$(16):LSET SPMT4$=SPACE$(16):LSET SPMT5$=SPACE$(16):LSET LFCR$=TRM$
5880 PUT #1,1:CLOSE #1
5890 RSTF%=1:GOSUB 2200
5900 GOSUB 2290:RSTF%=0
5910 S1$="       00":S2$="       00":LPC$="N":COMDTY$="N":CMNT$="N":CQ$="0":FM$=" 68":EBDG$="N":OPASS$="":SPASS$="":RETURN
5920 INPUT "^ENABLE HOST?   ^Y,N",HOST$
5930 IF HOST$="N" THEN RETURN
5940 Print "HOST ENABLED !": Sleep 1000
5950 RETURN
5960 INPUT "^IP? ^",IP$:IP$=PADL$(IP$,15," "):IP$=RIGHT$(IP$,15)
5970 PRINT "  IP CHANGED!":SLEEP 2000
5980 RETURN
5990 IF ERR()=14 THEN RETURN