100 Print "PLEASE WAIT...": Sleep 500
110 DEFSHR RA$,LIT23
120 OPEN "SETUP.DAT" FOR RANDOM AS #1 LEN = 52
130 FIELD #1,5 AS SIL$,5 AS SOL$,5 AS SQL$,5 AS SPL$,5 AS SCL$,4 AS SSCLT$,1 AS SLPC$,1 AS SH$,15 AS SIP$,4 AS SPORT$,2 AS LFCR$
140 GET #1,1
150 ILEN$=SIL$:OLEN$=SOL$:QLEN$=SQL$:PLEN$=SPL$:CLEN$=SCL$:SCLT$=SSCLT$:LPC$=SLPC$:HOST$=SH$:IP$=LTRIM$(SIP$):PORT$=SPORT$:CLOSE #1:PORT%=VAL(PORT$)
160 ILEN#=VAL(ILEN$):OLEN#=VAL(OLEN$):PLEN#=VAL(PLEN$):CLEN#=VAL(CLEN$):QLEN#=VAL(QLEN$):O%=VAL(OCNT$)
170 Open "Com2: TRM13 EVENT" for Input as #6
180 On Event #6 Gosub 890
190 Flush #6: X$="": XA$=""
200 Input #6, X$
210 If RA$="1" then gosub 290: goto 250
220 If RA$="2" then Gosub 580: goto 250
230 If RA$="3" then gosub 490
240 Print #6, CHR$(6)
250 Delevent #6: Close #6: RA$=""
260 If OP%=1 then Print "Report Complete!": Sleep 1000
270 If OP%=2 then Print "Report Canceled!": Sleep 1000
280 goto 960
290 OP%=1
300 OPEN "INBOUND.DAT" FOR RANDOM AS #1 LEN=36
310 FIELD #1, 8 AS REC_ID$, 8 AS IN_WT$, 8 AS IN_T$, 10 AS IN_D$, 2 AS LFCR$
320 FOR I% = 1 TO ILEN#
330 Time#=Timer()
340 GET #1, I%
350 Print using "Snd:###_!!!!!!!!"; I%; REC_ID$
360 IF REC_ID$ = "        " THEN GOTO 440
370 a$=REC_ID$ + "," + IN_WT$ + "," + IN_T$ + "," + IN_D$
380 PRINT #6, CHR$(2); a$; CHR$(3)
390 If XA$=CHR$(6) then goto 440
400 If Timer()>Time# + 10 then goto 420
410 If XA$<>CHR$(21) then goto 390
420 Print #6, CHR$(21); Space$(37); CHR$(3)
430 I%=ILEN#: OP%=2
440 XA$=""
450 NEXT I%
460 CLOSE #1
470 If OP%=1 then Print #6, CHR$(23); Space$(37); CHR$(3)
480 Return
490 KILL "INBOUND.DAT": PRINT "Initializing... ": Sleep 200
500 OPEN "INBOUND.DAT" FOR RANDOM AS #1 LEN=36
510 FIELD #1, 8 AS REC_ID$, 8 AS IN_WT$, 8 AS IN_T$, 10 AS IN_D$, 2 AS LFCR$
520 FOR I%=1 TO ILEN#
530 LSET REC_ID$=ESP$:RSET IN_WT$=ESP$:RSET IN_T$=ESP$:RSET IN_D$=SPACE$(10):LSET LFCR$=TRM$
540 PUT #1, I%
550 NEXT I%
560 CLOSE #1: Sleep 200
570 RETURN
580 OP%=1: j%=0
590 OPEN "OUTBOUND.DAT" FOR RANDOM AS #1 LEN=77
600 FIELD #1,8 AS A$,8 AS B$,8 AS C$,8 AS D$,16 AS E$,8 AS F$,19 AS G$,2 AS H$
610 FOR I% = 1 TO OLEN#
620 Time#=Timer()
630 GET #1, I%
640 Print using "SND:###_!!!!!!!!"; I%; A$
650 IF A$ = "        " THEN GOTO 740
660 j%=I%
670 b$=A$ + "," + C$ + "," + B$ + "," + D$ + "," + E$ + "," + Left$(G$,10) + "," + Right$(G$,8)
680 PRINT #6, CHR$(2); b$; CHR$(3); CHR$(13)
690 If XA$=CHR$(6) then goto 740
700 If Timer()>Time# + 10 then goto 720
710 If XA$<>CHR$(21) then goto 690
720 Print #6, CHR$(21); Space$(72); CHR$(3)
730 I%=OLEN#: OP%=2
740 XA$=""
750 NEXT I%
760 CLOSE #1
770 If OP%<>1 then Return
780 Print #6, CHR$(23); Space$(72); CHR$(3)
790 If j%=0 then Return
800 KILL "OUTBOUND.DAT": PRINT "Initializing... ": Sleep 200
810 OPEN "OUTBOUND.DAT" FOR RANDOM AS #2 LEN = 77
820 FIELD #2,8 AS A$,8 AS B$,8 AS C$,8 AS D$,16 AS E$,8 AS F$,19 AS G$,2 AS H$
830 FOR I%=1 TO OLEN#
840 LSET A$=ESP$:RSET B$=ESP$:RSET C$=ESP$:RSET D$=ESP$:LSET E$=SPACE$(16):RSET F$=ESP$:LSET G$=SPACE$(19):LSET H$=TRM$
850 PUT #2, I%
860 NEXT I%
870 CLOSE #2
880 RETURN
890 If Len(X$)<>0 then goto 930
900 Print "Invalid Command": Sleep 500
910 Flush #6: X$="": Input #6, X$
920 XA$="": Return
930 XA$=Left$(X$,1)
940 Flush #6: X$="": Input #6, X$
950 Return
960 Print "PLEASE WAIT..."
970 CFFLG%=1
980 CHAIN "file1.bas"